ESP-WROOM-02(ESP8266)で乾電池駆動の温湿度計を作ってみた

#include <ESP8266HTTPClient.h>
#include <ESP8266WiFi.h>

ADC_MODE(ADC_VCC); 

#include <SPI.h>
#include "BME280SpiSw.h" 

#define SERIAL_BAUD 115200
#define CSEL_PIN 5
#define MOSI_PIN 13
#define MISO_PIN 12
#define SCLK_PIN 14 

BME280SpiSw::Settings settings(CSEL_PIN, MOSI_PIN, MISO_PIN, SCLK_PIN);
BME280SpiSw bme(settings); 

const char WLAN_SSID[] = "wifi-ssid";
const char WLAN_PASS[] = "wifi-password"; 

const IPAddress addr(192, 168, 0, 251);
const IPAddress gwip(192, 168, 0, 1);
const IPAddress mask(255, 255, 255, 0); 

const char TSDB_HOST[] = "influxdb.example.com";
const int  TSDB_PORT   = 8086;
const char TSDB_PATH[] = "/write?db=weather";
const char TSDB_USER[] = "user";
const char TSDB_PASS[] = "password"; 

void setup() {
  Serial.begin(SERIAL_BAUD);
  Serial.println(); 

  while (!bme.begin()) {
    Serial.println("Could not find BME280 sensor!");
    delay(1000);
  } 

  WiFi.config(addr, gwip, mask, gwip);
  if (WiFi.SSID() != WLAN_SSID) {
    WiFi.persistent(true);
    WiFi.mode(WIFI_STA);
    WiFi.setAutoConnect(true);
    WiFi.begin(WLAN_SSID, WLAN_PASS);
  }

  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
  }
}

void loop() {
  int vcc = ESP.getVcc();

  float temp(NAN), hum(NAN), pres(NAN);
  BME280::TempUnit tempUnit(BME280::TempUnit_Celsius);
  BME280::PresUnit presUnit(BME280::PresUnit_hPa);
  bme.read(pres, temp, hum, tempUnit, presUnit); 

  String payload = "temperature,locate=room value=" + String(temp) + "\n";
  payload += "pressure,locate=room value=" + String(pres) + "\n";
  payload += "humidity,locate=room value=" + String(hum) + "\n";
  payload += "vcc,locate=room value=" + String(vcc) + "\n";
  Serial.println("payload=" + payload);

  if (WiFi.status() == WL_CONNECTED) {
    WiFiClient client;
    HTTPClient http;
    http.begin(client, TSDB_HOST, TSDB_PORT, TSDB_PATH);
    http.setAuthorization(TSDB_USER, TSDB_PASS);
    int ret = http.POST(payload);
    http.writeToStream(&Serial);
    http.end();
    Serial.println("ret=" + String(ret)); 

    WiFi.persistent(false);
    WiFi.disconnect();
  } 

  // enter deepsleep for 3600 seconds
  ESP.deepSleep(3600 * 1000 * 1000, WAKE_RF_DEFAULT);
  delay(1000);
}